6dc8b752e0- Add Detekt configuration (`detekt.yml`) with custom rules - Apply Detekt plugin to all subprojects - Configure Detekt tasks in Gradle workflow - Update Gradle dependency versions to include Detekt plugin ## Motivation and Context Enhance static code analysis for improved code quality. ## Breaking Changes No ## Types of changes - [x] CI update - [ ] Bug fix (non-breaking change which fixes an issue) - [ ] New feature (non-breaking change which adds functionality) - [ ] Breaking change (fix or feature that would cause existing functionality to change) - [ ] Documentation update ## Checklist <!-- Go over all the following points, and put an `x` in all the boxes that apply. --> - [x] I have read the [MCP Documentation](https://modelcontextprotocol.io) - [x] My code follows the repository's style guidelines - [x] New and existing tests pass locally - [ ] I have added appropriate error handling - [ ] I have added or updated documentation as needed
67 lines
1.5 KiB
Kotlin
67 lines
1.5 KiB
Kotlin
import dev.detekt.gradle.extensions.FailOnSeverity
|
|
|
|
plugins {
|
|
id("mcp.dokka")
|
|
alias(libs.plugins.detekt)
|
|
alias(libs.plugins.ktlint)
|
|
alias(libs.plugins.kover)
|
|
}
|
|
|
|
dependencies {
|
|
dokka(project(":kotlin-sdk-core"))
|
|
dokka(project(":kotlin-sdk-client"))
|
|
dokka(project(":kotlin-sdk-server"))
|
|
|
|
kover(project(":kotlin-sdk-core"))
|
|
kover(project(":kotlin-sdk-client"))
|
|
kover(project(":kotlin-sdk-server"))
|
|
"kover"(project(":integration-test"))
|
|
}
|
|
|
|
subprojects {
|
|
apply(plugin = "org.jlleitschuh.gradle.ktlint")
|
|
apply(plugin = "org.jetbrains.kotlinx.kover")
|
|
apply(plugin = "dev.detekt")
|
|
|
|
detekt {
|
|
config = files("$rootDir/detekt.yml")
|
|
buildUponDefaultConfig = true
|
|
failOnSeverity.set(FailOnSeverity.Never)
|
|
}
|
|
}
|
|
|
|
dokka {
|
|
moduleName = "MCP Kotlin SDK"
|
|
|
|
dokkaPublications.html {
|
|
includes.from("docs/moduledoc.md")
|
|
}
|
|
}
|
|
|
|
ktlint {
|
|
filter {
|
|
exclude("**/generated*/**")
|
|
}
|
|
}
|
|
|
|
kover {
|
|
reports {
|
|
filters {
|
|
includes.classes("io.modelcontextprotocol.kotlin.sdk.*")
|
|
excludes {
|
|
annotatedBy("kotlin.Deprecated")
|
|
classes("io.modelcontextprotocol.kotlin.sdk.models.*") // temporary
|
|
classes("io.modelcontextprotocol.kotlin.sdk.models.infrastructure.*") // generated
|
|
}
|
|
}
|
|
total {
|
|
log {
|
|
}
|
|
verify {
|
|
rule {
|
|
minBound(65)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|